[PATCH v2] AC_HEADER_MAJOR: port to glibc 2.25

classic Classic list List threaded Threaded
4 messages Options
Reply | Threaded
Open this post in threaded view
|

[PATCH v2] AC_HEADER_MAJOR: port to glibc 2.25

Eric Blake-3
glibc 2.25 is deprecating the namespace pollution of sys/types.h
injecting major(), minor(), and makedev() into the compilation
environment, with a warning that insists that users include
<sys/sysmacros.h> instead.  However, because the expansion of
AC_HEADER_MAJOR didn't bother checking sys/sysmacros.h until
after probing whether sys/types.h pollutes the namespace, it was
not defining MAJOR_IN_SYSMACROS, with the result that code
compiled with -Werror chokes on the deprecation warnings because
it was not including sysmacros.h.

In addition to fixing autoconf (which only benefits projects
that rebuild configure after this fix is released), we can also
give a hint to distros on how they can populate config.site with
a cache variable to force pre-existing configure scripts without
the updated macro to behave sanely in the presence of glibc 2.25
(the documentation is especially useful since that cache variable
is no longer present in autoconf after this patch).

Note that mingw lacks major/minor/makedev in any of its standard
headers; for that platform, the behavior of this macro is unchanged
(code using the recommended include formula will get a compile error
when trying to use major(), whether before or after this patch); but
for now, it is assumed that programs actually concerned with
creating devices are not worried about portability to mingw.  If
desired, a later patch could tighten AC_HEADER_MAJOR to fail at
configure time if the macros are unavailable in any of the three
system headers, but that semantic change is not worth mixing into
this patch.

* lib/autoconf/headers.m4 (AC_HEADER_MAJOR): Drop check for
major within sys/types.h; it interferes with the need to check
sysmacros.h first.
* doc/autoconf.texi (Particular Headers) <AC_HEADER_MAJOR>: Expand
details on usage, and on workarounds for non-updated projects.

Signed-off-by: Eric Blake <[hidden email]>
---

Thanks for the wordsmithing help, and forcing me to think about
mingw. This version updates some wording, and changes the macro
to leave the relative order of mkdev.h vs. sysmacros.h checking
unchanged (by merely weakining the sys/types.h check to no longer
care whether the macros are present).

 doc/autoconf.texi       | 35 +++++++++++++++++++++++++++++++----
 lib/autoconf/headers.m4 | 30 ++++++++++++++----------------
 2 files changed, 45 insertions(+), 20 deletions(-)

diff --git a/doc/autoconf.texi b/doc/autoconf.texi
index d3ccf19..0eb84de 100644
--- a/doc/autoconf.texi
+++ b/doc/autoconf.texi
@@ -5970,10 +5970,37 @@ Particular Headers
 @cvindex MAJOR_IN_SYSMACROS
 @hdrindex{sys/mkdev.h}
 @hdrindex{sys/sysmacros.h}
-If @file{sys/types.h} does not define @code{major}, @code{minor}, and
-@code{makedev}, but @file{sys/mkdev.h} does, define
-@code{MAJOR_IN_MKDEV}; otherwise, if @file{sys/sysmacros.h} does, define
-@code{MAJOR_IN_SYSMACROS}.
+Detect the headers required to use @code{makedev}, @code{major}, and
+@code{minor}.  These functions may be defined by @file{sys/mkdev.h},
+@code{sys/sysmacros.h}, or @file{sys/types.h}.
+
+@code{AC_HEADER_MAJOR} defines @code{MAJOR_IN_MKDEV} if they are in
+@file{sys/mkdev.h}, or @code{MAJOR_IN_SYSMACROS} if they are in
+@file{sys/sysmacros.h}.  If neither macro is defined, they are either in
+@file{sys/types.h} or unavailable.
+
+To properly use these functions, your code should contain something
+like:
+
+@verbatim
+#include <sys/types.h>
+#ifdef MAJOR_IN_MKDEV
+# include <sys/mkdev.h>
+#elif MAJOR_IN_SYSMACROS
+# include <sys/sysmacros.h>
+#endif
+@end verbatim
+
+Note: Configure scripts built with Autoconf 2.69 or earlier will not
+detect a problem if @file{sys/types.h} contains definitions of
+@code{major}, @code{minor}, and/or @code{makedev} that trigger compiler
+warnings upon use.  This is known to occur with GNU libc 2.25, where
+those definitions are being deprecated to reduce namespace pollution.
+If it is not practical to use Autoconf 2.70 to regenerate the configure
+script of affected software, you can work around the problem by setting
+@samp{ac_cv_header_sys_types_h_makedev=no}, as an argument to
+@command{configure} or as part of a @file{config.site} site default file
+(@pxref{Site Defaults}).
 @end defmac

 @defmac AC_HEADER_RESOLV
diff --git a/lib/autoconf/headers.m4 b/lib/autoconf/headers.m4
index 0c44973..72262c1 100644
--- a/lib/autoconf/headers.m4
+++ b/lib/autoconf/headers.m4
@@ -427,31 +427,29 @@ fi

 # AC_HEADER_MAJOR
 # ---------------
+# Thanks to glibc 2.25 deprecating macros in sys/types.h, coupled with
+# back-compat to autoconf 2.69, we need the following logic:
+# Check whether <sys/types.h> compiles.
+# If <sys/mkdev.h> compiles, assume it provides major/minor/makedev.
+# Otherwise, if <sys/sysmacros.h> compiles, assume it provides the macros.
+# Otherwise, either the macros were provided by <sys/types.h>, or do
+# not exist on the platform.  Code trying to use these three macros is
+# assumed to not care about platforms that lack the macros.
 AN_FUNCTION([major],     [AC_HEADER_MAJOR])
 AN_FUNCTION([makedev],   [AC_HEADER_MAJOR])
 AN_FUNCTION([minor],     [AC_HEADER_MAJOR])
 AN_HEADER([sys/mkdev.h], [AC_HEADER_MAJOR])
 AC_DEFUN([AC_HEADER_MAJOR],
-[AC_CACHE_CHECK(whether sys/types.h defines makedev,
- ac_cv_header_sys_types_h_makedev,
-[AC_LINK_IFELSE([AC_LANG_PROGRAM([[@%:@include <sys/types.h>]],
- [[return makedev(0, 0);]])],
- [ac_cv_header_sys_types_h_makedev=yes],
- [ac_cv_header_sys_types_h_makedev=no])
-])
-
-if test $ac_cv_header_sys_types_h_makedev = no; then
+[AC_CHECK_HEADERS_ONCE([sys/types.h])
 AC_CHECK_HEADER(sys/mkdev.h,
  [AC_DEFINE(MAJOR_IN_MKDEV, 1,
    [Define to 1 if `major', `minor', and `makedev' are
     declared in <mkdev.h>.])])
-
-  if test $ac_cv_header_sys_mkdev_h = no; then
-    AC_CHECK_HEADER(sys/sysmacros.h,
-    [AC_DEFINE(MAJOR_IN_SYSMACROS, 1,
-       [Define to 1 if `major', `minor', and `makedev'
- are declared in <sysmacros.h>.])])
-  fi
+if test $ac_cv_header_sys_mkdev_h = no; then
+  AC_CHECK_HEADER(sys/sysmacros.h,
+  [AC_DEFINE(MAJOR_IN_SYSMACROS, 1,
+     [Define to 1 if `major', `minor', and `makedev'
+      are declared in <sysmacros.h>.])])
 fi
 ])# AC_HEADER_MAJOR

--
2.7.4


Reply | Threaded
Open this post in threaded view
|

Re: [PATCH v2] AC_HEADER_MAJOR: port to glibc 2.25

Zack Weinberg-2
On Wed, Sep 14, 2016 at 3:00 PM, Eric Blake <[hidden email]> wrote:
>
> Thanks for the wordsmithing help, and forcing me to think about
> mingw. This version updates some wording, and changes the macro
> to leave the relative order of mkdev.h vs. sysmacros.h checking
> unchanged (by merely weakining the sys/types.h check to no longer
> care whether the macros are present).

This version looks good to me.

zw

Reply | Threaded
Open this post in threaded view
|

Re: [PATCH v2] AC_HEADER_MAJOR: port to glibc 2.25

Zack Weinberg-2
In reply to this post by Eric Blake-3
Doh, one small correction:

> +@verbatim
> +#include <sys/types.h>
> +#ifdef MAJOR_IN_MKDEV
> +# include <sys/mkdev.h>
> +#elif MAJOR_IN_SYSMACROS
> +# include <sys/sysmacros.h>
> +#endif
> +@end verbatim

That should be `#elif defined MAJOR_IN_SYSMACROS`.  This was
originally my mistake and I just realized it _was_ a mistake, sorry.

(also applies to a couple of places in your gnulib patches)

zw

Reply | Threaded
Open this post in threaded view
|

Re: [PATCH v2] AC_HEADER_MAJOR: port to glibc 2.25

Eric Blake-3
On 09/14/2016 08:14 PM, Zack Weinberg wrote:

> Doh, one small correction:
>
>> +@verbatim
>> +#include <sys/types.h>
>> +#ifdef MAJOR_IN_MKDEV
>> +# include <sys/mkdev.h>
>> +#elif MAJOR_IN_SYSMACROS
>> +# include <sys/sysmacros.h>
>> +#endif
>> +@end verbatim
>
> That should be `#elif defined MAJOR_IN_SYSMACROS`.  This was
> originally my mistake and I just realized it _was_ a mistake, sorry.
>
> (also applies to a couple of places in your gnulib patches)
Good thing I haven't pushed yet!

You are correct that config.h either leaves those two macros undefined
or defines them to 1; so #if works as well as #ifdef, but only as long
as your compiler isn't warning about undefined macros used as
preprocessor conditionals during #if (C99 requires it to work, but it is
a very common warning to enable in gcc to prevent it as a lintian style
option).  So I could go either way as long as the two lines are
consistent, but the #ifdef approach seems less likely to bother people
that use the gcc warning.

--
Eric Blake   eblake redhat com    +1-919-301-3266
Libvirt virtualization library http://libvirt.org


signature.asc (617 bytes) Download Attachment